*save_checkpoint

*text_image chap_1.png center Chapter One
*temp usedepiali false

An amber blush peeks over the edge of the sky, heralding the arrival of dawn. You feel sleep's grip on the mortals of Hellas loosen. They'll soon rise, break their fasts, and tend to their duties.

By the time their work begins, you'll be back home in the Underworld, tucking into a platter of ambrosia-laced fruit and listening to the cries of the damned echo in the distance.

*fake_choice
    #I like the sound. They should be punished for their misdeeds.
        *set ruthless %+10
        *set criesofdead 1
        Tyrants, traitors, and thieves who thought to rise against King Zeus and either failed or got caught.

        Fools, the lot of them. If there's one thing you know about King Zeus and his brood, it is that they don't suffer those gladly.

        Neither do you, for that matter.
    #I hate the sound. Nobody deserves that kind of suffering.
        *set ruthless %-10
        *set criesofdead 2           
        King Zeus may have his reasons for torturing the poor souls, but that doesn't mean it's right to do so.

        Not without a proper trial. Not for all eternity. Not without giving them a chance to repent.
    #I'm used to the sound. Right or wrong, it's as familiar as birdsong.
        *set diplomacy %+10
        *set criesofdead 3
        King Zeus has his reasons for sentencing the poor souls to an eternity of suffering.

        Whether you agree with them or not isn't as important as keeping the peace—and the trade—between the Underworld and Olympus.

*page_break

It'll be a while yet before you hear them. For now, you hover above the stirring mortal realm. The Hellenic peninsula looks like a skeletal hand stretched out to sea, with hundreds upon hundreds of islands flanking its jagged fingers.

The Land of the Gods, the poets call it. Not because the gods dwell in it; because you rule over it. Regents, politicians, heroes. They may steer the ships, but you shape the tides.

Well. Not so much [i]you[/i].

Despite being older than any living mortal, you're still young for a goddess. 

Still uncovering the path woven for you by the Fates. 

*page_break 

So far, said path has led you to dominion over nightmares and a seat on the Messengers' Council. Your main duty? Instilling fear in mortals through terrible dreams. 

Some fade in time, others haunt them long after they wake. Some contain divine omens, others are harbingers of dread and nothing more. It's up to Zeus to decide which is which, and up to you to deliver them each night.

Luckily, you have a legion of daemons to aid you. Your Epiali, wraithlike creatures that move through shadows and blend into night, bound to you by the Fates.

You spread your arms, silently reaching out to them in the Halfrealm. It manifests beneath you, mantling the peninsula with shifting shadows.

This the poets call the Land of Dreams, but they are wrong. 

The Halfrealm isn't a land; it's a river. Chimerical and ever-changing, it flows through the gaps between Hellas and the Underworld, drawing slumbering mortals' psyches—and the Fates—appointed deities who would commune with them.

Your Epiali emerge from its gloomy waters when you summon them. The Halfrealm fades as they meet mid-air and surge toward you.

What shape do they take?
 
*fake_choice
    #Snakes.
        *set epiali 1
        *set choseepiali true
    #Bats.
        *set epiali 2
        *set choseepiali true
    #Ravens.
        *set epiali 3
        *set choseepiali true
    #Cats.
        *set epiali 4
        *set choseepiali true
    #Spiders.
        *set epiali 5
        *set choseepiali true

Like you, they are not tethered to the earth, and needn't abide by her rules.

They @{(epiali) slither toward you with their fangs bared, twilight catching on their gray scales|fly toward you, a swarm of jointed wings and silver fangs|fly toward you, a cloud of black feathers and gleaming beaks|stalk toward you with their fangs bared, twilight catching on their midnight-black fur|crawl toward you, a tangle of furry legs and glittering eyes}.

Their bodies blur and merge, forming twisting screens of shadow that show you the nightmares they inspired. A pilgrim showing up to the temple unclothed. A young mother losing all her teeth. A scholar forgetting all they know as they're about to deliver a lecture.

They may seem trivial, but they remind mortals to pour their libations and make their sacrifices. Their worship is your strength. Without it, you can't keep the cosmos safe, or the forces that would destroy it in check. 

Forces like the Giants. They had waged war on the pantheon long before you were born, but the realms still bear the scars.

*page_break

Sighing, you dismiss your daemons. Roll your shoulders back. Crack your neck. 

Though your Epiali lighten the load, you've had a tough shift. Most gods don't need sleep, but you could certainly use a  break.

How do you travel home?

*fake_choice
    #I have wings, powerful and lithe.
        *set flightstyle 1
        *set fitness %+15
        What do they look like?
        *fake_choice
            #Shimmery and marbled with veins, like the wings of a dragonfly.
                *set wingstyle 1
                A few flicks and you reach the jagged cliffs to the peninsula's south.
            #Feathered and inky black, like the wings of a raven. 
                *set wingstyle 2
                They cut through the wind before you swoop down on the jagged cliffs to the peninsula's south.
            #Webbed and flexible, like the wings of a bat.
                *set wingstyle 3
                They beat the wind, carrying you to the jagged cliffs that dominate the peninsula's south.
    #I conjure shadows. They can lift me, carry me, and, if need be, conceal me.
        *set flightstyle 2
        *set stealth %+15
        They swirl around you as you glide toward the jagged cliffs to the peninsula's south. 
    #I wear beautiful winged sandals, made of fine leather with dove-like feathers at the ankles.
        *set flightstyle 3
        *set demure %+10
        *set charm %+15
        You gently kick the air, gliding toward the jagged cliffs to the peninsula's south.

Once there, you slip into the cave closest to the highest peak.

No self-preserving mortal would brave the treacherous climb, let alone walk through the arched gateway inside.

The keystone is carved with the Underworld's most fearsome sentry to dissuade interlopers all the same: Cerberus, your father's three-headed dog. His snarling faces preside over two pillars that frame not an opening, but an abyss. Darker and smoother than the rock surrounding it.

And humming.

The dead, whispering from beyond.

The dead, warning other mortals not to cross the Dream Gate, lest they join them.

*page_break

As you approach it, a winged silhouette appears on the other side.

They step out of the gloom like a beam of sunlight piercing through gray clouds. 

Iris, deity of the rainbow and aide to Hermes, leader of the Messengers' Council.

When they spot you, their eyes change from soft blue to rose gold and a smile rounds their cheeks.

How do they address you?

*fake_choice
    #Melinoe.
        *set name "Melinoe"
    #Demi.
        *set name "Demi"
    #Makaria.
        *set name "Makaria"
    #Zoe.
        *set name "Zoe"
    #Nyxie.
        *set name "Nyxie"
    #Something else
        What is your name?
        *input_text name

"$!{name}. I was hoping I'd catch you on your way back."

You frown. "More orders from Hermes?"

The god rarely delivers them himself. He's far too busy overseeing communications between the realms, not to mention guiding the souls of the dead to the Underworld's main gates.

His latest scroll instructed you to increase nightmare severity in the island of Leukas, and to cook up something particularly dreadful for its lord.

It isn't the first time he has made such requests. The Giants have a new queen, and there are rumors of an uprising. Zeus is on a push for worship as a result. According to Hermes, he wishes for the Leukans to increase their nightly libations to match those of neighboring city-states.

Unfortunately for you, their lord is as hard to sway as he is to spook.

When you realize Hermes might want to talk to you, you feel…

*fake_choice
    #Nervous. I want to impress Hermes and the Olympians.
        *set dutiful %+25
        *set diplomacy %+10
        What if you failed them somehow?

        The Lord of Leukas has been tough to crack. You [i]think[/i] you made him cower enough, but you can't keep doubt from creeping into your mind. 
    #Confident. I have faith in myself and my abilities.
        *set leadership %+25
        *set charm %+10
        You are the goddess of nightmares. The Lord of Leukas has been tough to crack, yes, but you're certain you made him cower enough.

        Whatever Hermes wants, the mortal has nothing to do with it.
    #Calm. Whatever he has to say, I'll take it in stride.
        *set diplomacy %+25
        *set charm %+10
        You did your best to make the Lord of Leukas cower.

        He has been tough to crack, however. If your attempts thus far haven't been good enough, you'll own up to it and do better next time.
    #Irritated. I don't appreciate being micromanaged.
        *set charm %-25
        *set ruthless %+10
        You know how to make mortals cower. Gods too. 
        
        And even if the Lord of Leukas has been tougher than most to crack, you're not about to let Hermes—or anyone else—give you a hard time for it.
        
*page_break

Iris shakes their head.

"He does not. Though that reminds me, how did the assignment go?"

You consider the question, for the answer is complicated.

Last night, you found the Lord of Leukas dreaming of the same ship he's been dreaming of for weeks. A real ship—his impression of it in the Halfrealm is so vivid, you've come to recognize it in the island's shipyard. Almost ready to sail, but the finishing touches call to him even in his sleep.

You've attempted to deliver your message by wrecking it before, but it only appears to encourage his obsession with hull stability and outrigger placement, rather than his worship.

This time, however, you think you had a breakthrough.

*page_break At Long Last

As you searched the depths of his dream—the Leukan port, bright despite the lack of warmth and the murky currents lining it—you caught a glimmer of panic beneath the waves. 

A wedding. [i]His[/i] wedding. Not a vision, or a memory.

*page_break A Fear

You coaxed it to the surface, letting his dread spill over the dreamscape like ink.

The port melted away, replaced by a bustling agora adorned with all the trappings of a great feast. The Lord of Leukas stood tall and proud at the heart of it, brown skin glinting in the torchlight, a garland of gold laurel resting on his dark curls, and a tidy beard enhancing his strong features. 

Before him stood his bride, veiled and silent.

To be the goddess of nightmares is to embody them. To be a Messenger goddess is to give them meaning.

On this occasion, you had chosen to…

*fake_choice
    #Be front and center as the beautiful bride.
        *set demure %-25
        *set therondream 1
        Admired by all beneath her veil.
    #Lead the wedding rituals as a solemn-faced priestess.
        *set leadership %+25
        *set therondream 2
        Clad in flowing robes, you began waxing lyrical about divine blessings.
    #Blend in—and observe closely—as a guest.
        *set stealth %+25
        *set therondream 3
        A wizened old lady, perching on a bench and watching the unveiling unfold.
    #Take the form of one of my daemons.
        *set daemonhandling %+25
        *set therondream 4
        A shadowy @{(epiali) snake, curled up|bat, perching|raven, perching|cat, curled up|spider, tucked away} in a corner.


The Lord of Leukas reached for @{(therondream > 1) his bride's veils|it} with a perfectly pleasant expression. 

But you had sensed the fear lurking behind his smile as he removed the lovely fabric.

Then he had wavered. The music and the merriment halted around you, and the Halfrealm peeked through the cracks in the dreamscape. His gaze found @{(therondream > 3) yours, even in your animal form,|yours} and the fear that had crept into it vanished.

*page_break

It's not unusual for mortals to sense your presence in their dreams. Who wouldn't feel a knife pressed to their back?

But this was different. His expression had softened with recognition.

Not only had you felt seen but also…welcomed.

"$!{name}?" Iris probes, yanking you back to yourself.

What do you tell them?

*fake_choice
    #The truth. I would never lie to another deity, especially not one as decent as Iris.
        *set dutiful %+20
        You confess the difficulties you faced. How much the Lord of Leukas's perfectly pleasant nuptials baffled you. How he seemed to welcome your presence.

        There is no judgment in Iris's gaze as they listen, only encouragement. 

        "And yet, you rose to the challenge," they say when you're done. "He may be mortal-born, but I hear he possesses the might and cunning of a hero. You should have more faith in yourself, ${name}."

        Their words fill you with reassurance. You smile, grateful for their counsel.
    #The truth. I have no reason to lie to them, and would only do so in extenuating circumstances.
        *set diplomacy %+20
        You tell them how tricky it has been to unearth the Lord of Leukas's fears and describe the nightmare you brought forth. 

        "Sounds like you've had quite the task," they say. "Talk in Olympus is that he possesses the heart of a hero, if not the blood. Sometimes, the strongest minds are the hardest to reason with."

        You smile, reassured by their words. They've always had a knack for wise counsel.
    #A lie. I would never show weakness in front of another god, regardless of how nice they are.
        *set charm %-20
        "Crushed it." You shrug.

        Wariness creeps into Iris's eyes, now a guarded charcoal. 
        
        "I'm glad," they offer. "The Olympians find it hard to believe he isn't the son of a god, what with his dauntlessness and knack for cunning."

        You raise your eyebrows, impressed in spite of yourself. It's unusual for a mortal without a drop of divine blood to have earned himself such a reputation.
    #A lie. Knowledge is as powerful as worship, and I prefer not to hand it out for free.
        *set cunning %+20
        "Smooth sailing."
        
        The words slide off your tongue, natural as breathing.
        
        "Why do you ask?" you prod.
        
        "Some in Olympus believe him too arrogant for a mortal who doesn't possess a drop of divine blood," Iris offers. Their disapproval is obvious. Not at the mortal, you realize, but at the gods who would diminish his achievements due to his bloodline.

        You click your tongue, feigning disappointment yourself.

        If nothing else, it'll keep them sweet.

*page_break
        
"I do have a message for you," the aide confirms, adjusting the strap of their satchel. They don't pull a scroll from it, though. Instead, they shoot you a sheepish grin and add, "I'm to remind you King Hades and Queen Persephone expect you back at the palace at once."

Ah, yes. After the sun rises, you will travel to Olympus with your family to discuss the subject of marriage under the guise of a state banquet. 

[i]Your[/i] marriage, to King Zeus's son Ares.

You haven't seen the God of War since you were both children. Not that it matters to Zeus.

Such a match would solidify the relationship between your realms, and present a united front against the Giants who evaded imprisonment and would wage another war. It's why the King suggested it.

But how do you feel about it?

*fake_choice
    #I will marry whoever I must to keep the realms safe.
        *set marriage 1
        *set ruthless %-20
        A conflict with the Giants would wreak havoc on the pantheon, not to mention Hellas. 

        You deities won't survive it unscathed, but at least you'll survive it.

        The same can't be said for most mortals.

        If your marriage prevents their annihilation, so be it.
    #I intend to marry to further my position in the pantheon.
        *set marriage 2
        *set cunning %+20
        Marriage is about forging alliances and securing power.

        As far as politically beneficial matches go, you could do worse than an Olympian prince.
    #I have no intention of marrying someone I don't love.
        *set marriage 3
        *set demure %-20
        Some may think you naive. Selfish, even. But you can't think of a worse fate than being trapped in a loveless union for all eternity. 

        You deserve better than that. 

        Everyone does.
    #I have no interest in marriage, for any reason.
        *set marriage 4
        *set dutiful %-20
        You refuse to let your future be defined by some archaic ritual. 
        
        There are plenty of ways to prove your commitment to another if you're so inclined, and far more effective shows of strength.

*page_break

Marriage or no, reconnecting with Ares should be interesting.

The pair of you used to be inseparable at feasts. Always sneaking into the kitchens to gorge on ambrosia cake, playing knucklebones under the table and watching drakons hatch in the oak grove his mother planted when he was born.

The boy you remember had kind eyes, dimpled cheeks, and perpetually syrup-stained fingers.

The god he has grown into sounds nothing like that boy. A brute on and off the battlefield, and quite the philanderer.

At least that's what the poets say.

You've changed too, you suppose. And when it comes to matters of the heart…

*fake_choice
    #I'm quite the heartbreaker myself, and thoroughly enjoy the pleasures of the flesh.
        *set background 1
        *set demure %-10
        You won't judge him for doing the same.
    #I'm wary of love ever since having my heart broken by a callous god.
        *set background 2
        *set diplomacy %+10
        Oh, he put on a good show, especially in the beginning. Made you feel like you were in one of the poets' epic love stories. 
        
        So convincing was his performance, you forgot they always end in tragedy.

        You refuse to make that mistake again.
    #I've never lain—or fallen in love—with anyone, though I often wonder what it might be like.
        *set background 3
        *set virgin true
        *set demure %+10
        The thought alone warms your cheeks.

        Oh, you've had your fair share of suitors, some of which you even indulged for a little while. 
        
        But, ultimately, they didn't set your heart alight.
    #I'm still haunted by the memory of the long-dead mortal I loved from afar.
        *set background 4
        *set dutiful %-10
        A poet you met while summering with your grandmother, right before assuming your role in the pantheon. When you were foolish enough to allow yourself to grow attached, but wise enough to know it wouldn't end well for either of you if you acted on it.

        So you didn't. He grew old and died happy; you took on your title and live on.

        But that doesn't mean you've forgotten.

*page_break

"I'm to remind you not to dilly-dally, lest you be late. Sorry," Iris says, once again pulling you away from your wandering thoughts.

You can't help but sigh. Your parents' own marriage was brokered by King Zeus and though it's a happy one, it wasn't always. 

Perhaps that's why they have been so on edge—and on your back about every little thing—since receiving the thunder god's invitation.

*fake_choice
    #I understand why. It's a crucial time for all of us.
        *set ruthless %-10
        *set parents %+10
        *set parentsrel 1
    #I find it incredibly irksome. It's my future, not theirs.
        *set dutiful %-10
        *set parents %-10
        *set parentsrel 2
    #As have I. But we're doing our best to navigate it with grace.
        *set diplomacy %+10
        *set parents %+5
        *set parentsrel 3
      
"I had better get going then," you tell Iris. "Thank you."

They nod and smooth the skirt of their chitoniskos, checking the wineskin hooked through the girdle is secure.

Iris is a meticulous deity. The scrolls they carry are neatly packed, the messages written in them delivered on time. But they're always extra careful with that particular wineskin. Its contents—water from the river Styx—are used by the gods to swear Stygian oaths. 

When they're not carrying out errands for Hermes, Iris bears witness to such oaths—the most sacred a deity can swear. The river water binds them to their word, and going back on it has dire consequences.

What that means, exactly, is unclear, but your parents have always warned you against it. 

According to them, to break a Stygian oath is to break oneself.

*page_break

Iris finishes checking their girdle and gives your shoulder a squeeze. "Good luck." 

They take wing, leaving a rainbow in their wake, and you to wish for some good luck indeed.

*page_break Travel Through the Gate

One moment, you're in the cave. The next, you're in the Underworld.

Eternal dusk blankets your father's kingdom. There are no stars in the endless sky, but there are souls. Tiny, glowing motes that rustle in the breeze like iridescent leaves.  

The mortals they belonged to have drunk from the river Lethe and embraced sweet oblivion.

But some souls cling to one another even after that. They roam the Underworld together, as though bound by something stronger than death.

Stronger than memory.

You think it's…

*fake_choice
    #Romantic.
        *set charm %+10
        A love that remains when everything else is gone.
    #Comforting.
        *set ruthless %-10
        Just because mortal lifespans are short doesn't mean the love they find during them is fleeting.
    #Sad.
        *set dutiful %-10
        Mortal lifespans are far too fleeting.
    #Ridiculous.
        *set grumpysouls true
        *set ruthless %+10
        There's no way of knowing they're the same pair of souls.

*page_break

You breathe in the familiar scent of home. Cypress and water mint, hemlock and evening dew.

The Dream Gate perches in a clearing surrounded by mossy woodland on the Lethe's banks. On the other side of the river, rolling fields of asphodel curve all the way to Elysium, the acropolis your father built when he was crowned king after one of the gods' many hard-won wars. 

But on this side, the forest stretches all the way to the Erebus Mountains. You can just about make out their spiky peaks in the distance, and the stained sky above Tartarus beyond them. 

The pit that keeps the damned contained is forever on the brink of a storm. 

Some of their cries escape the abyss, echoing through the gloom. So far away, you could shut them out if you wish. @{(criesofdead) But why wouldn't you want to hear the sound of justice being served?|And you do, ignoring the dread stealing up your spine|They fade into the background, another note in the symphony that surrounds you. The river babbling, the souls buzzing, the leaves teetering. You ease into the tune, feel yourself soften in its embrace}. 

Then you notice the poppy poking out of the horn pillar to your right, like an arrow pointed at your face.

*page_break Take a Closer Look

Morpheus placed it right at your eye level so you wouldn't miss it. 
 
Countless others are draped around his half of the gate, but this one is shinier, newer, more obnoxious. Its pale petals fold toward you, releasing a soft, enticing aroma.

If you were mortal, it would put you to sleep. A peaceful sleep, the kind that yields sweet dreams, even if Morpheus is far from a sweet god. 

In fact, the God of Dreams is positively insufferable.

*page_break
 
You're supposed to complement each other. Be opposite ends of the same scale.

Where you secure worship through fear, Morpheus does so through comfort. Where you sow terror and doubt, he invites love and cheer. Where you deliver awful omens, he regales auspicious prophecies. 

The Fates willed it so. They're the unravellers of Chaos, the essence at the heart of all things, and neither mortals nor gods should question their judgment.

But it's hard not to when it comes to Morpheus. Dreams may be his domain, but he's far from dreamy. There's no bear he won't poke, no dog he won't wake, no deity he won't vex.

Every time he beats you back to the Underworld, he adds another poppy to his side of the gate. Your side is covered in flowers too, one for each time you returned before him.

*fake_choice
    #Crocuses, purple-veined and full of secrets.
        *set flower 1
        *set choseflower true
        *set cunning %+10
    #Daffodils, with proud stalks and bold, honey-hued bulbs.
        *set flower 2
        *set choseflower true
        *set demure %-10
    #Flowering quince, a perennial as strong and resilient as you.
        *set flower 3
        *set choseflower true
        *set fitness %+10
    #Nightshade, black-petalled and, like you, inconspicuously deadly. 
        *set flower 4
        *set choseflower true
        *set stealth %+10
        *set ruthless %+10

Mortals plant them in your honor in Hellas, where they wither and die and are reborn with the seasons. But here, they're forever in bloom.

They wrap around the ivory pillar, a sea of @{(flower) violet|gold|red|obsidian} squaring up to Morpheus's army of white poppies.

You can easily imagine the god smirking when he realized he won this round. Shrugging his moth-like wings, flipping back his long, silver hair.

Plotting how he'll lord it over you next time you cross paths.

*fake_choice
    #Urgh. Smug, bothersome, infuriatingly handsome Morpheus.
        *set Morpheus %+10
    #It will be a @{(flower) crocus|daffodil|quince flower|nightshade} taunting [i]him[/i] next time. I'll make sure of it.
        *set Morpheus %+5
        *set charm %-10
        *set competitive true
    #That's his prerogative. I would rather focus on Ares.
        *set Morpheus %-5
        *set Ares %+10
    #That's his prerogative. I would rather focus on the mortal.
        *set Morpheus %-5
        *set Theron %+5
        *set dutiful %+10
    *if competitive = false
        #If Hermes didn't encourage it, I wouldn't partake.
            *set Morpheus %-10

You leave the gate-turned-battlefield behind and make for one of the bridges curling over the Lethe.

As much as you love flying, the walk to Elysium is too beautiful not to take on foot. Nice to give your @{(flightstyle) wings|shadows|sandals} a break, besides. 

The state banquet is quite the change to your routine. Had Zeus not summoned you, you would spend the majority of the time between nightmare runs partaking in your favorite pastime.

*fake_choice
    #Weaving beautiful tapestries.
        *set hobby 1
        *set dutiful %+10
        You love coaxing threads into whatever takes your fancy.

        It requires great dedication and skill, even for a goddess, but that only makes it more satisfying.
    #Training at the gymnasium.
        *set hobby 2
        *set fitness %+10
        You love to hit the sand and get the ichor pumping.

        From running to wrestling to javelin-throwing, there isn't a sport you don't enjoy.
    #Playing the aulos.
        *set hobby 3
        *set charm %+10
        You're no Muse, but you love performing for the Underworld's denizens all the same.

        They always join in. There's singing, dancing, and merriment, and it isn't rare for you to leave an impromptu revel to tend to your duties, only to find it still unfolding upon your return. 
    #Dice and board games.
        *set hobby 4
        *set competitive true
        *set cunning %+10
        Strategy, luck, skill, chance—you're game for anything, so long as you get to play.

        Even better if you get to win.

Of course, there will be none of that today.

*page_break

As you stroll through the winding path, asphodel-crowned dunes to one side, misty woodland to the other, you catch sight of something among the trees.

Something that shouldn't be there.

An empusa.

The daemons are one of your aunt Hecate's creations gone wrong. Or right, if what she intended was to birth monstrous creatures that feed on the blood of children. You never know with her.

Dagger-toothed and flame-haired, this one is tearing through the thicket, its hoofed donkey leg pounding the ground, its bronze leg cleaving it.

It must've escaped from Hecate's estate, and it's charging toward the gate. If it gets out, not only will mortals suffer, but the Underworld will appear weak in the eyes of Olympus.

You can't let it reach the gate. 

Determined, you conjure your weapon.

*fake_choice
    #A bident. Forged by Cyclops using the purest adamant, just like my father's.
        *set choseweapon true
        *set weapon 1
        *set parents %+5
        *set fitness %+5
        Its silver prongs are shaped like crescent moons, its neck carved with @{(flower) crocuses|daffodils|flowering quince|nightshades}. 
    #A bow. Gifted to me by the goddess Artemis, Olympus's finest huntress.
        *set choseweapon true
        *set weapon 2
        *set dutiful %+5
        *set stealth %+5
        It has limbs that cascade into a string that never breaks, and a constant supply of arrows you can call upon at will.
    #A scythe. I like to cut down my enemies, sow fear before I reap death.
        *set choseweapon true
        *set weapon 3
        *set fitness %+5
        *set ruthless %+5
        The blade is silver adamant, the shaft pure obsidian and carved with @{(flower) crocuses|daffodils|flowering quince|nightshades}.
    #A sling. I prefer my weapons lethal yet easy to disguise.
        *set choseweapon true
        *set weapon 4
        *set stealth %+10
        *set cunning %+5
        Braided from flax that never rots, its length changes as you need it to, and it makes for a convincing belt when you want to carry it on you but still be inconspicuous. 
    #A staff. Deadly if I need it to be, but a deterrent first and foremost.
        *set choseweapon true
        *set weapon 5
        *set ruthless %-5
        *set fitness %+5
        Crafted of pomegranate wood harvested from your mother's famous orchard. Its glossy sheen never chips, and its adamant tip is shaped like a @{(epiali) snake|bat|raven|cat|spider}.

Your fingers tighten around it as souls scurry out of the empusa's path, blinking like fireflies in distress.

It hasn't seen you yet—its reptilian eyes are anchored on the gate.

What do you do?

*choice
    #Block its path. I want to confront it head on, in a fair fight.
        *set fitness %+25
        *set killedempusa true
        You lunge, slamming down between the empusa and the gate with enough momentum to make the forest shake.
        
        It digs its hoof into the dirt, halting a few feet from where you stand. Its slit pupils narrow with hunger as it glares at you, flaming hair blazing. It flexes its claws, licks its muzzle.
        
        You grin, daring it to take a bite. It leaps at you, baring its bent, blood-crusted teeth.

        Time seems to slow, but you move fast as lightning. @{(weapon) The bident's shaft hits the ground. You wait until the empusa's jaws are a few inches from your throat before crouching. By the time it realizes its mistake, it has already impaled itself on the twin prongs you aimed at its chest. Its limp body slides all the way to the ground, limbs still splayed|An arrow materializes in your hand. You nock it as the empusa comes at you, release it before it has a chance to fully open its weapon of a mouth. Two more follow, one to pin it against the trunk of a tree, and another to put it out of its misery|The blade of your scythe flashes as it slices through the wind, then it buries into the empusa's side. It yelps before crumpling to the ground. You don't give it a chance to get up, ripping the scythe out of its ribcage and bringing it down on its neck|The sling unfurls from your hand like a snake, already loaded with a pellet of purest adamant. You whirl it above your head, launch it at the empusa as it leaps at you. The pellet goes straight through its chest, knocking it to the ground, where it lies stone-still|You use the shaft of your staff to shove the empusa to the ground, craning your neck to avoid its snapping jaws. Before it has a chance to get up, you bring down your staff. One well-aimed bash is all it takes for it to go limp}.

        *if weapon = 2
            You stride up to the cypress, pull the arrows out of its flesh. The empusa slumps to the ground and the tree releases a sigh.
            *goto deadempusa
        *else
            *goto deadempusa
    #Sneak up on it and kill it before it even sees me coming.
        *set stealth %+25
        *set killedempusa true
        You sidle up to the unsuspecting empusa, @{(flightstyle) wings close to the ground|shrouded in a cloak of shadow|the swish of your winged sandals masked by the sighs of the forest}.

        The trees cover you as you catch up to the monster. Strings of drool cling to its bent, blood-crusted teeth, as if it can already taste young flesh. Its clawed fingers flex, its hair erupts in even angrier flames.

        You lunge, @{(weapon) bident|bow|scythe|sling|staff} ready. @{(weapon) You hurl the weapon at the wicked beast. Twin prongs sink into its scaly ribcage and|You nock an arrow as it materializes between your fingers and release it in the same breath. It slices through the wind, finding the wicked beast's neck. Two more follow before|You bring your scythe down on the wicked beast's neck. The blade flashes like lightning, then slices through thick scales and finds bone. The grass trembles as|A pellet of pure adamant is already snuggled into the strap, and you swing the cord in the air before letting it loose. It collides with the wicked beast's ribcage and|Your first strike knocks the wicked beast back, your second delivers the killing blow before} it hits the ground with a loud thud.

        Its death is quick, almost painless. 

        *if weapon = 2
            You stroll toward its limp body, pull the arrows out of its flesh as gently as you can.
            *goto deadempusa
        *else 
            *goto deadempusa
    #Command it to stop. No need for bloodshed when I possess a goddess's will.
        *set leadership %+25
        You keep your @{(weapon) bident|bow|scythe|sling|staff} at the ready as you emerge from the trees, @{(flightstyle) spreading your wings wide|wreathed in shadows|graceful and sure-footed}.

        The empusa halts and whips its head toward you. But its body remains pointed at the gate, clawed hands twisting, flaming hair blazing.

        You hold its glare, even after it bares its bent, blood-crusted teeth at you and a low, beastly growl unfurls from its throat.

        "Please," you scoff. Your tone is easy, dismissive, but your demeanor is firm.

        The empusa frowns. You take a step forward and it takes one back. Then, as if realizing what it's done, it lets out another snarl. But it doesn't come any closer.

        "You can either scatter," you offer, @{(weapon) leaning on your bident|waving your bow|flashing your scythe|casually swinging your sling|tapping the ground with your staff}, "or you can face my wrath."

        The creature hesitates, eyes darting between where you stand and the gate.

        "Run along now." Your voice is clear as the Lethe's surface.

        Defeat softens the empusa's features. Its shoulders slump and it turns around with a huff. You hide your grin until it has dragged itself back into the woods.
        *goto liveempusa
    #Use my Epiali to lure it away from the gate without hurting it.
        *set ruthless %-25
        *set daemonhandling %+20
        *set usedepiali true
        You summon a few Epiali from the shadows.

        They dart toward the empusa in a shadowy heap, becoming more solid the closer they get. You drift behind them, using the trees as cover.

        The empusa halts and sniffs the air, as though it can sense the daemons creeping up on it. This close, you can see the strings of drool clinging to its bent, blood-crusted teeth, how sharp the claws jutting out of its splayed hands are. 

        @{(epiali) The snakes leap at the creature, fangs bared|The bats fling themselves at the creature, wings wide|The ravens descend on the creature, cawing wildly|The cats pounce on the creature, hissing and flashing their claws|The spiders swarm the creature, baring their fangs}. The empusa rears back with a startled cry.

        The Epiali form a line between it and the gate, lunging at it every time it attempts to come forward. The angrier it grows, the brighter its flaming hair blazes. A growl unfurls from its throat, but your Epiali don't falter, driving it away from the gate, further into the forest.

        Soon, it stops glancing back at the ivory pillars, stops doing anything but attempt to catch the @{(epiali) snakes|bats|ravens|cats|spiders} between its jaws.

        *if (((epiali = 1) or (epiali = 4)) or (epiali = 5))
            Knowing it will follow, your Epiali make a run for it, scattering into the woods. The empusa is hot on their heels, screeching as it gives chase.
            *goto liveempusa
        *else
            Knowing it will follow, your Epiali fly into the woods. The empusa gives chase, screeching as it swipes at the branches.
            *goto liveempusa

*label deadempusa
*page_break

The empusa's halo of flames gives a final flutter before sputtering out, leaving a divot of singed earth behind. Without it, the creature's head looks like an extinguished rag torch. Its face seems more animal, less monster.

Ichor is splashed everywhere. Spilling over the empusa's scales, smeared on the tree trunks, sprayed across your face.

The golden liquid that flows through gods' veins also nourishes your daemons. And already the wood is drinking it in. 

Roots spring up around the corpse, wrapping around it like arms. They pull it closer to the forest floor, to the worms and maggots wriggling out of the soil. 

There will be nothing left of it when you return tomorrow. 

Death is what keeps this realm fed, after all.

*achieve slayempusa

*goto main01

*label liveempusa
*page_break

You watch its halo of flames waver through the tree trunks, shrinking from a torch to a candle before it completely disappears.

@{(usedepiali) The Epiali won't stop taunting it until they|It will take it a long while to} reach Hecate's estate, beyond the pit of Tartarus. 

The forest sighs around you, the souls settle back into their happy flitting. 

*achieve spareempusa

*label main01
*page_break Where's That Rest At

You return to the river and kneel on the leafy banks to splash some water on your face.

When you're done, you catch a glimpse of your reflection on the shimmering surface. You're

*fake_choice
    #A svelte, slender-limbed goddess.
        *set bodytype 1
    #A voluptuous goddess, all supple curves. 
        *set bodytype 2
    #A strong goddess, toned and well-built.
        *set fitness %+5
        *set bodytype 3

But the night has taken its toll. You can already imagine your mother's comments, the way she'll fret about every aspect of your appearance before you set off for Zeus's kingdom. 

The thought inevitably makes you wonder about your future. If you're being honest with yourself…

*fake_choice
    #The thought of seeing Ares again after all this time excites me.
        *set Ares %+10
    #I'm rather intrigued by the Lord of Leukas and his strange nightmare.
        *set Theron %+10
    #I can't stop thinking about beating Morpheus back from my next nightmare run.
        *set Morpheus %+10

You rise and @{(flightstyle) shake your wings|your shadow wavers|the wings at your ankles flicker}.

Whatever your future holds, you best hurry up and meet it.
    
*choice
    #Continue to the next chapter.
        *finish Chapter 2
    *if (not(choice_randomtest)) #Restore to the previous checkpoint.
        *restore_checkpoint